看到這裡，你應該已經很了解GDT了，如果還不了解GDT。請看這篇文章：一個操作系統的實現(2)-認識保護模式，認識保護模式那篇文章的最後詳細介紹了由16位尋址升級到32位尋址而引入的GDT。
LDT（Local Descriptor Table）：從名字上面就可以看出來它與GDT（Gobal Descriptor Table）的區別。GDT是全局描述符表，LDT是局部描述符表（相對於GDT）。
下面仍然是從代碼的角度講解什麼是LDT。主要講解在上一節的基礎上增加的代碼。在文章的最後會附上所有代碼。為了描述LDT，在上一節的基礎上添加了如下代碼：
[SECTION .gdt] ... LABEL_DESC_LDT: Descriptor 0, LDTLen - 1, DA_LDT ; LDT ... SelectorLDT equ LABEL_DESC_LDT -LABEL_GDT ... [SECTION .s16] ... ; 初始化 LDT 在 GDT 中的描述符 xor eax, eax mov ax, ds shl eax, 4 add eax, LABEL_LDT mov word [LABEL_DESC_LDT+2], ax eax, 16 mov byte [LABEL_DESC_LDT+4], al mov byte [LABEL_DESC_LDT+7], ah ; 初始化 LDT 中的描述符 xor eax,eax mov ax,ds shl eax,4 add eax,LABEL_CODE_A mov word[LABEL_LDT_DESC_CODEA+2], ax shr eax,16 mov byte[LABEL_LDT_DESC_CODEA+4], al mov byte[LABEL_LDT_DESC_CODEA+7], ah ... [SECTION .s32]; 32 位代碼段. 由實模式跳入. ... ; Load LDT mov ax,SelectorLDT lldt ax jmp SelectorLDTCodeA:0 ; 跳入局部任務 ... ; LDT [SECTION .ldt] ALIGN 32 LABEL_LDT: ; 段基址 段界限 屬性 LABEL_LDT_DESC_CODEA: Descriptor 0, CodeALen - 1, DA_C + DA_32;Code,32位 LDTLen equ $ - LABEL_LDT ; LDT 選擇子 SelectorLDTCodeA equ LABEL_LDT_DESC_CODEA - LABEL_LDT + SA_TIL ; END of [SECTION .ldt] ; CodeA (LDT, 32 位代碼段) [SECTION .la] ALIGN 32 [BITS 32] LABEL_CODE_A: mov ax, SelectorVideo mov gs, ax ; 視頻段選擇子(目的) mov edi, (80* 12 + 0) * 2 ; 屏幕第 10 行, 第 0 列。 mov ah, 0Ch ; 0000:黑底 1100: 紅字 mov al, 'L' mov [gs:edi], ax ; 准備經由16位代碼段跳回實模式 jmp SelectorCode16:0 CodeALen equ $ - LABEL_CODE_A ; END of [SECTION .la]
現在來看上面的代碼。
首先，
在GDT中增加了一個描述符和描述符對應的選擇子。
然後，
增加了兩個節，在上述代碼的最後兩段。分別是新的描述符表LDT和代碼段，這個代碼段的描述符在LDT中。用來演示LDT的如何使用。
接下來看16位代碼段中的初始化代碼，
這裡的初始化代碼對描述符進行初始化。包括兩個部分，一個是初始化LDT在GDT中的描述符，另一個是初始化LDT中的描述符。
最後，在32位代碼段中增加如下內容：
; Load LDT mov ax,SelectorLDT lldt ax jmp SelectorLDTCodeA:0 ; 跳入局部任務
這裡面有個lldt ax。它與lgdt類似，lgdt用來將gdt的基址（32位）與界限（16位）加載到gdtr中。類似地，lldt是將ldt描述符的選擇子加載到ldtr中。
你看看上面的LDT的結構，與GDT結構是不是非常像。是的，LDT與GDT有兩個最主要的差別，一個是上面所說LDT使用lldt加載的對象是選擇子而GDT使用lgdt加載的對象是gdt的基地址和界限（通常用一個在內存中的結構體表示）。另外一個差別就是LDT的選擇子TI位與GDT的選擇子的TI位不同。還記的TI嗎？它是選擇子結構中的一位。不記得的話看下面的選擇子結構：
15 14 13 12 11 10 9 8 7 6 5 4 3 2 1 0 描述符索引 TI RPL
第2位是TI位，上一節課我也不清楚它用來干什麼的。到這裡再來解釋它就很清晰了。
仔細觀察上面LDT選擇子與GDT選擇子，你會發現：LDT的選擇子比GDT的選擇子多了一個SA_TIL屬性。在pm.inc中找到它的定義如下：
SA_TIL EQU 4
結合上圖可知，SA_TIL將選擇子SelectorLDTCodeA的TI位置為1。實際上，TI位便是用來區別GDT的選擇子和LDT的選擇子的關鍵所在。如果TI被置為1,系統將從局部描述符表LDT中讀取描述符；如果TI位為0,系統將從全局描述符表GDT中讀取描述符。
因此，當上面的代碼運行到jmp SelectorLDTCodeA:0處時，系統會從LDT中找到LABEL_LDT_DESC_CODEA描述符，並跳轉到相應的段中。
本例中LDT中的代碼比較簡單，只是在屏幕上輸入一個字符L。
不難想象，在[SECTION .s32]中打印完“In Protect Mode now.”這個字符串後，一個紅色的字符L將會出現。程序運行結果如下：
現在，你對LDT應該有了大致的了解了吧。簡單來說，他是一種描述符表，與GDT差不多，只不過它的選擇子的TI位必須置1.在運用它時，需要先用lldt指令加載ldtr，lldt的操作數是GDT中用來描述LDT的描述符。
上面的例子中的LDT只有一個代碼段。隨著以後的逐漸深入，我們還可以在其中增加更多的段，比如數據段、堆棧段等。通過，我們可以把一個單獨的任務所用到的所有東西封裝在LDT中，這種思想是多任務處理的一個雛形。
下面是完整代碼：
; ==========================================
; pmtest3.asm
; 編譯方法：nasm pmtest3.asm -o pmtest3.com
; ==========================================
%include "pm.inc" ; 常量, 宏, 以及一些說明
org 0100h
jmp LABEL_BEGIN
[SECTION .gdt]
; GDT
; 段基址, 段界限 , 屬性
LABEL_GDT: Descriptor 0, 0, 0 ; 空描述符
LABEL_DESC_NORMAL: Descriptor 0, 0ffffh, DA_DRW ; Normal 描述符
LABEL_DESC_CODE32: Descriptor 0, SegCode32Len - 1, DA_C + DA_32 ; 非一致代碼段, 32
LABEL_DESC_CODE16: Descriptor 0, 0ffffh, DA_C ; 非一致代碼段, 16
LABEL_DESC_DATA: Descriptor 0, DataLen - 1, DA_DRW+DA_DPL1 ; Data
LABEL_DESC_STACK: Descriptor 0, TopOfStack, DA_DRWA + DA_32; Stack, 32 位
LABEL_DESC_LDT: Descriptor 0, LDTLen - 1, DA_LDT ; LDT
LABEL_DESC_VIDEO: Descriptor 0B8000h, 0ffffh, DA_DRW ; 顯存首地址
; GDT 結束
GdtLen equ $ - LABEL_GDT ; GDT長度
GdtPtr dw GdtLen - 1 ; GDT界限
dd 0 ; GDT基地址
; GDT 選擇子
SelectorNormal equ LABEL_DESC_NORMAL - LABEL_GDT
SelectorCode32 equ LABEL_DESC_CODE32 - LABEL_GDT
SelectorCode16 equ LABEL_DESC_CODE16 - LABEL_GDT
SelectorData equ LABEL_DESC_DATA - LABEL_GDT
SelectorStack equ LABEL_DESC_STACK - LABEL_GDT
SelectorLDT equ LABEL_DESC_LDT - LABEL_GDT
SelectorVideo equ LABEL_DESC_VIDEO - LABEL_GDT
; END of [SECTION .gdt]
[SECTION .data1] ; 數據段
ALIGN 32
[BITS 32]
LABEL_DATA:
SPValueInRealMode dw 0
; 字符串
PMMessage: db "In Protect Mode now. ^-^", 0 ; 進入保護模式後顯示此字符串
OffsetPMMessage equ PMMessage - $$
StrTest: db "ABCDEFGHIJKLMNOPQRSTUVWXYZ", 0
OffsetStrTest equ StrTest - $$
DataLen equ $ - LABEL_DATA
; END of [SECTION .data1]
; 全局堆棧段
[SECTION .gs]
ALIGN 32
[BITS 32]
LABEL_STACK:
times 512 db 0
TopOfStack equ $ - LABEL_STACK - 1
; END of [SECTION .gs]
[SECTION .s16]
[BITS 16]
LABEL_BEGIN:
mov ax, cs
mov ds, ax
mov es, ax
mov ss, ax
mov sp, 0100h
mov [LABEL_GO_BACK_TO_REAL+3], ax
mov [SPValueInRealMode], sp
; 初始化 16 位代碼段描述符
mov ax, cs
movzx eax, ax
shl eax, 4
add eax, LABEL_SEG_CODE16
mov word [LABEL_DESC_CODE16 + 2], ax
shr eax, 16
mov byte [LABEL_DESC_CODE16 + 4], al
mov byte [LABEL_DESC_CODE16 + 7], ah
; 初始化 32 位代碼段描述符
xor eax, eax
mov ax, cs
shl eax, 4
add eax, LABEL_SEG_CODE32
mov word [LABEL_DESC_CODE32 + 2], ax
shr eax, 16
mov byte [LABEL_DESC_CODE32 + 4], al
mov byte [LABEL_DESC_CODE32 + 7], ah
; 初始化數據段描述符
xor eax, eax
mov ax, ds
shl eax, 4
add eax, LABEL_DATA
mov word [LABEL_DESC_DATA + 2], ax
shr eax, 16
mov byte [LABEL_DESC_DATA + 4], al
mov byte [LABEL_DESC_DATA + 7], ah
; 初始化堆棧段描述符
xor eax, eax
mov ax, ds
shl eax, 4
add eax, LABEL_STACK
mov word [LABEL_DESC_STACK + 2], ax
shr eax, 16
mov byte [LABEL_DESC_STACK + 4], al
mov byte [LABEL_DESC_STACK + 7], ah
; 初始化 LDT 在 GDT 中的描述符
xor eax, eax
mov ax, ds
shl eax, 4
add eax, LABEL_LDT
mov word [LABEL_DESC_LDT + 2], ax
shr eax, 16
mov byte [LABEL_DESC_LDT + 4], al
mov byte [LABEL_DESC_LDT + 7], ah
; 初始化 LDT 中的描述符
xor eax, eax
mov ax, ds
shl eax, 4
add eax, LABEL_CODE_A
mov word [LABEL_LDT_DESC_CODEA + 2], ax
shr eax, 16
mov byte [LABEL_LDT_DESC_CODEA + 4], al
mov byte [LABEL_LDT_DESC_CODEA + 7], ah
; 為加載 GDTR 作准備
xor eax, eax
mov ax, ds
shl eax, 4
add eax, LABEL_GDT ; eax <- gdt 基地址
mov dword [GdtPtr + 2], eax ; [GdtPtr + 2] <- gdt 基地址
; 加載 GDTR
lgdt [GdtPtr]
; 關中斷
cli
; 打開地址線A20
in al, 92h
or al, 00000010b
out 92h, al
; 准備切換到保護模式
mov eax, cr0
or eax, 1
mov cr0, eax
; 真正進入保護模式
jmp dword SelectorCode32:0;執行這一句會把 SelectorCode32 裝入`cs`,並跳轉到Code32Selector:0處
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
LABEL_REAL_ENTRY: ; 從保護模式跳回到實模式就到了這裡
mov ax, cs
mov ds, ax
mov es, ax
mov ss, ax
mov sp, [SPValueInRealMode]
in al, 92h ; ┓
and al, 11111101b ; ┣ 關閉 A20 地址線
out 92h, al ; ┛
sti ; 開中斷
mov ax, 4c00h ; ┓
int 21h ; ┛回到 DOS
; END of [SECTION .s16]
[SECTION .s32]; 32 位代碼段. 由實模式跳入.
[BITS 32]
LABEL_SEG_CODE32:
mov ax, SelectorData
mov ds, ax ; 數據段選擇子
mov ax, SelectorVideo
mov gs, ax ; 視頻段選擇子
mov ax, SelectorStack
mov ss, ax ; 堆棧段選擇子
mov esp, TopOfStack
; 下面顯示一個字符串
mov ah, 0Ch ; 0000: 黑底 1100: 紅字
xor esi, esi
xor edi, edi
mov esi, OffsetPMMessage ; 源數據偏移
mov edi, (80 * 10 + 0) * 2 ; 目的數據偏移。屏幕第 10 行, 第 0 列。
cld
.1:
lodsb
test al, al
jz .2
mov [gs:edi], ax
add edi, 2
jmp .1
.2: ; 顯示完畢
call DispReturn
; Load LDT
mov ax, SelectorLDT
lldt ax
jmp SelectorLDTCodeA:0 ; 跳入局部任務
; ------------------------------------------------------------------------
DispReturn:
push eax
push ebx
mov eax, edi
mov bl, 160
div bl
and eax, 0FFh
inc eax
mov bl, 160
mul bl
mov edi, eax
pop ebx
pop eax
ret
; DispReturn 結束---------------------------------------------------------
SegCode32Len equ $ - LABEL_SEG_CODE32
; END of [SECTION .s32]
; 16 位代碼段. 由 32 位代碼段跳入, 跳出後到實模式
[SECTION .s16code]
ALIGN 32
[BITS 16]
LABEL_SEG_CODE16:
; 跳回實模式:
mov ax, SelectorNormal
mov ds, ax
mov es, ax
mov fs, ax
mov gs, ax
mov ss, ax
mov eax, cr0
and al, 11111110b
mov cr0, eax
LABEL_GO_BACK_TO_REAL:
jmp 0:LABEL_REAL_ENTRY ; 段地址會在程序開始處被設置成正確的值
Code16Len equ $ - LABEL_SEG_CODE16
; END of [SECTION .s16code]
; LDT
[SECTION .ldt]
ALIGN 32
LABEL_LDT:
; 段基址 段界限 屬性
LABEL_LDT_DESC_CODEA: Descriptor 0, CodeALen - 1, DA_C + DA_32 ; Code, 32 位
LDTLen equ $ - LABEL_LDT
; LDT 選擇子
SelectorLDTCodeA equ LABEL_LDT_DESC_CODEA - LABEL_LDT + SA_TIL
; END of [SECTION .ldt]
; CodeA (LDT, 32 位代碼段)
[SECTION .la]
ALIGN 32
[BITS 32]
LABEL_CODE_A:
mov ax, SelectorVideo
mov gs, ax ; 視頻段選擇子(目的)
mov edi, (80 * 12 + 0) * 2 ; 屏幕第 10 行, 第 0 列。
mov ah, 0Ch ; 0000: 黑底 1100: 紅字
mov al, 'L'
mov [gs:edi], ax
; 准備經由16位代碼段跳回實模式
jmp SelectorCode16:0
CodeALen equ $ - LABEL_CODE_A
; END of [SECTION .la]
