今天安裝VMWare過程中藍屏了，重啟再次安裝發現：
The MSI 'C:\DOCUME~1\LOCALS~1\Temp\vmware_1295537967\vmware workstation.msi' failed
不管換多少個版本，都是上面的結果，原因是vmware在系統中有殘留文件以及注冊表信息。測試了網上一些刪除操作，發現都不行。
但我發現下面的方法行：
退出所有的安全軟件（安裝存在沖突）
將以下代碼保存為文本文件，改後綴為.cmd然後以管理員身份執行，命令會自動清理以前殘留的VMware信息。
卸載VMware.cmd
cls
@echo off
CLS
color 0a
Title 卸載 VMware
set vmbit=
IF "%PROCESSOR_ARCHITECTURE%" neq "x86" set vmbit=64
echo 你確定要卸載 VMware 8 嗎?
echo 按任意鍵繼續卸載 VMware 8 !!!&pause>nul
echo 正在刪除服務和設備,可能需要幾分鐘,請稍後...
echo 如果三分鐘後還沒動靜,請在卸載批處理上敲一下回車鍵後繼續等待...
msiexec.exe /x vmwarevmcisockets.msi /qn /norestart
msiexec.exe /x vmwarevmcisockets64.msi /qn /norestart
vnetlib%vmbit%.exe -- stop authd >nul 2>nul
vnetlib%vmbit%.exe -- uninstall authd >nul 2>nul
net stop VMAuthdService >nul 2>nul
sc delete VMAuthdService >nul 2>nul
net stop VMwareHostd >nul 2>nul
sc delete VMwareHostd >nul 2>nul
vnetlib%vmbit%.exe -- stop dhcp >nul 2>nul
vnetlib%vmbit%.exe -- uninstall dhcp >nul 2>nul
vnetlib%vmbit%.exe -- stop nat >nul 2>nul
vnetlib%vmbit%.exe -- uninstall nat >nul 2>nul
vnetlib%vmbit%.exe -- stop bridge >nul 2>nul
vnetlib%vmbit%.exe -- uninstall bridge >nul 2>nul
vnetlib%vmbit%.exe -- stop userif >nul 2>nul
vnetlib%vmbit%.exe -- uninstall userif >nul 2>nul
vnetlib%vmbit%.exe -- stop adapter >nul 2>nul
vnetlib%vmbit%.exe -- uninstall adapter >nul 2>nul
rundll32 vnetlib%vmbit%.dll,VNL_RemoveAllNetworkDevices
net stop VMUSBArbService >nul 2>nul
sc delete VMUSBArbService >nul 2>nul
vnetlib%vmbit%.exe -- stop usb
vnetlib%vmbit%.exe -- uninstall usb
vnetlib%vmbit%.exe -- stop hcmon >nul 2>nul
vnetlib%vmbit%.exe -- uninstall hcmon >nul 2>nul
net stop vstor2-mntapi10-shared >nul 2>nul
sc delete vstor2-mntapi10-shared >nul 2>nul
vnetlib%vmbit%.exe -- stop vmkbd >nul 2>nul
vnetlib%vmbit%.exe -- uninstall vmkbd >nul 2>nul
net stop vmkbd >nul 2>nul
sc delete vmkbd >nul 2>nul
vnetlib%vmbit%.exe -- stop vmparport >nul 2>nul
vnetlib%vmbit%.exe -- uninstall vmparport >nul 2>nul
vnetlib%vmbit%.exe -- stop vmx86 >nul 2>nul
vnetlib%vmbit%.exe -- uninstall vmx86 >nul 2>nul
vnetlib.exe -- uninstall vmci
echo.
echo 取消DLL文件的注冊...
regsvr32 /u /s "%cd%\vmappcfg.dll"
regsvr32 /u /s "%cd%\vmappsdk.dll"
regsvr32 /u /s "%cd%\vmdbCOM.dll"
echo.
echo 刪除注冊表....
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\VMware, Inc." /f >nul 2>nul
reg delete "HKEY_CURRENT_USER\SOFTWARE\VMware, Inc." /f >nul 2>nul
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\VMware, Inc." /f >nul 2>nul
reg delete "HKEY_CURRENT_USER\SOFTWARE\Wow6432Node\VMware, Inc." /f >nul 2>nul
reg delete "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Drivers32" /f /v "VIDC.VMnc" >nul 2>nul
reg delete "HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows NT\CurrentVersion\Drivers32" /f /v "VIDC.VMnc" >nul 2>nul
reg delete "HKLM\SYSTEM\CurrentControlSet\Services\VMware" /f >nul 2>nul
echo.
echo 刪除文件...
rmdir /s /q "%AllUsersProfile%\Application Data\VMware" >nul 2>nul
rmdir /s /q "%AppData%\VMware" >nul 2>nul
rmdir /s /q "%CommonProgramFiles%\VMware" >nul 2>nul
rmdir /s /q "%WinDir%\inf\VMware" >nul 2>nul
IF "%PROCESSOR_ARCHITECTURE%" neq "x86" rmdir /s /q "%CommonProgramFiles(x86)%\VMware" >nul 2>nul
del /f /q "%WinDir%\system32\vmnc.dll" >nul 2>nul
del /f /q "%WinDir%\SysWOW64\vmnc.dll" >nul 2>nul
del /f /q "%WinDir%\system32\vnetinst.dll" >nul 2>nul
del /f /q "%WinDir%\system32\vnetlib*.dll" >nul 2>nul
del /f /q "%windir%\system32\drivers\vstor2-mntapi10-shared.sys" >nul 2>nul
del /f /q "%WinDir%\SysWOW64\drivers\vstor2-mntapi10-shared.sys" >nul 2>nul
del /f /q "%AllUsersProfile%\桌面\VMware.lnk" >nul 2>nul
del /f /q "%AllUsersProfile%\Desktop\VMware.lnk" >nul 2>nul
del /f /q "%USERPROFILE%\桌面\VMware.lnk" >nul 2>nul
del /f /q "%USERPROFILE%\Desktop\VMware.lnk" >nul 2>nul
del /f /q "%WinDir%\system32\drivers\vmnet*.sys" >nul 2>nul
del /f /q "%WinDir%\system32\drivers\vmparport.sys" >nul 2>nul
del /f /q "%WinDir%\system32\drivers\VMkbd.sys" >nul 2>nul
del /f /q "%WinDir%\system32\drivers\vmx86.sys" >nul 2>nul
del /f /q "%WinDir%\system32\drivers\vmusb.sys" >nul 2>nul
del /f /q "%WinDir%\system32\drivers\vmci.sys" >nul 2>nul
del /f /q "%WinDir%\system32\vmnetdhcp.exe" >nul 2>nul
del /f /q "%WinDir%\system32\vmnat.exe" >nul 2>nul
del /f /q "%WinDir%\system32\vmnetbridge.dll" >nul 2>nul
del /f /q "%WinDir%\SysWOW64\vmnetdhcp.exe" >nul 2>nul
del /f /q "%WinDir%\SysWOW64\vmnat.exe" >nul 2>nul
echo.
echo 刪除 __vmware_user__ 賬戶和用戶組 ...
net localgroup users __vmware_user__ /del >nul 2>nul
net localgroup __vmware__ /del >nul 2>nul
net user __vmware_user__ /del >nul 2>nul
echo.
echo 恢復配置文件...
ver|find "6.">nul && (set profilepath=%AllUsersProfile%)
ver|find "5.">nul && (set profilepath=%AllUsersProfile%\Application Data)
start /wait str.exe preferences.ini 0 0 /R /asc:"%cd%" /asc:"VMwareDir" /A >nul 2>nul
start /wait str.exe environments.xml 0 0 /R /asc:"%cd%" /asc:"VMwareDir" /A >nul 2>nul
start /wait str.exe "%profilepath%\VMware\hostd\config.xml" 0 0 /R /asc:"%cd%" /asc:"VMwareDir" /A >nul 2>nul
start /wait str.exe "%profilepath%\VMware\hostd\datastores.xml" 0 0 /R /asc:"%cd%" /asc:"VMwareDir" /A >nul 2>nul
start /wait str.exe "%profilepath%\VMware\hostd\stats\hostAgentStats.xml" 0 0 /R /asc:"%profilepath%\VMware" /asc:"hostdDir" /A >nul 2>nul
start /wait str.exe "%profilepath%\VMware\hostd\config.xml" 0 0 /R /asc:"%profilepath%\VMware" /asc:"hostdDir" /A >nul 2>nul
net stop "VMware NAT Service" >nul 2>nul&&sc delete "VMware NAT Service" >nul 2>nul
net stop VMnetDHCP >nul 2>nul&&sc delete VMnetDHCP >nul 2>nul
net stop VMnetAdapter >nul 2>nul&&sc delete VMnetAdapter >nul 2>nul
net stop vmusb >nul 2>nul&&sc delete vmusb >nul 2>nul
net stop VMnetBridge >nul 2>nul&&sc delete VMnetBridge >nul 2>nul
net stop vmci >nul 2>nul&&sc delete vmci >nul 2>nul
echo.
sc delete "vstor2-mntapi10-shared" >nul 2>nul
sc delete "VMparport" >nul 2>nul
sc delete VMUSBArbService >nul 2>nul
sc delete VMnetDHCP >nul 2>nul
sc delete "VMware NAT Service" >nul 2>nul
sc delete VMAuthdService >nul 2>nul
sc delete VMnetuserif >nul 2>nul
sc delete VMnetAdapter >nul 2>nul
sc delete vmkbd >nul 2>nul
sc delete vmx86 >nul 2>nul
echo.
pause>nul|echo 卸載完成,最好重新啟動一下計算機,因為有些驅動可能需要重啟後才能刪除......
exit
